Kaks Scilab skripti kolmefaasilise AC ahela arvutuseks

Selliste skriptide koostamiseks kulub aega vaid mõni minut – saate arvutuste tulemused, kusjuures olete tõendanud nende õigsust (kui lähteandmed on sisestatud õigesti), saate ka arvutuste protokolli.

mode(1) // Neutraaljuhita 3-faasiline ahel In=0 
// Andmete sisestamine: 
aa=sin(%pi/3) // konstant sin(30deg)
V=220*[1+%i*0; -.5-%i*aa; -.5+%i*aa]
Z=[100; -%i*100; 100]
Y=1 ./Z

Un=sum(V .*Y)/sum(Y)
Un_mod= abs(Un)

Iph=(V-Un) .*Y
Iph_mod=abs(Iph)
Iph_arg=[];
for k=1:3, Iph_arg(k)=atan(imag(Iph(k)),real(Iph(k)))*180/%pi;end
Iph_arg
Uh_mod=abs(Iph .* Z)
Pph = real(Z .* Iph .* conj(Iph))

// Tulemiste toendamine:
S_ss=sum(V .*conj(Iph))
S_zz=sum(Z .* Iph .* conj(Iph))
In=0; sum_Iph=sum(Iph)

mode(3) // Neutraaljuhiga 3-faasiline ahel In<>0 
// Andmete sisestamine: 
aa=sin(%pi/3) // konstant sin 30deg
Vph=220*[1+%i*0; -.5-%i*aa; -.5+%i*aa]
Z=[100; -%i*100; 100]
Zn=10
Y=1 ./Z

Un=sum(Vph .*Y)/(sum(Y) +1/Zn)
Un_mod= abs(Un)

Iph=(Vph-Un) .*Y
Iph_arg=[];
for k=1:3, Iph_arg(k)=atan(imag(Iph(k)),real(Iph(k)))*180/%pi;end
Iph_arg

In=Un/Zn // Neutraal 
In_mod= abs(In)
Iph_mod=abs(Iph)

Uph_mod=abs(Iph .* Z)
Pph = real(Z .* Iph .* conj(Iph))

// Tulemiste toendamine:
S_ss=sum(Vph .*conj(Iph))
S_zz=sum(Z .* Iph .* conj(Iph))+Un *conj(In)
In
sum_Iph=sum(Iph)

Kui olete ära õppinud valemite kirjutamise (arvutile arusaadaval kujul), siis selliste skriptide koostamiseks kulub aega tõesti vaid mõni minut, mis on tühiselt vähe võrreldes arvutustega kalkulaatoril – muuseas samade valemite järgi: valemid on vajalikud igal juhul.
Scilab paketiga on kaasas põhjaik abi-info (prantsuse ja inglise keeles); abi saamiseks tippida käsuaknasse nt help atan help real help sin jne. Scilab manuaal on pikk, harilikult järgitakse näidis-skripte -- selliseid nagu siin esitatud skriptid, kus on näha for tsükli, massiivide, kompleksarvude kasutamise ühed võimalused (tegelikult on rohkem võimalusi).
Ärge unustage tulemuste kopeerimist käsuaknast faili, mis on tulemuste protokoll.
E.S. Apr 2006