Assembleri kasutamine

Nagu näete, ei ole mälumudelite TINY, SMALL, COMPACT, MEDIUM ja LARGE globaalsete andmetega puhul mingit probleemi. Te peate nad lihtsalt deklareerima*.ASM failis võtmesõnaga extern ja seejärel võite kohe tarvitada tolle muutuja nime tema sisu kasutamiseks, näiteks:

*.C failis:

...
int	i, j;
extern  char  *nimi, buf[20];
...
strcpy(buf, nimi);	/* kasutame *.ASM failis 
                           defineeritud muutujat */

*.ASM failis

...
	EXTRN _i : WORD
	EXTRN _j : WORD
	.DATA
	DB   nimi	"Jaanus", 0 ;nimi, mille lõppu lisame nulli 
                              ;C keele funktsioonide jaoks
...
     MOV	AX, i		;kasutame *.C failis defineeritud
     MOV	BX, j		;muutujaid

See kõik on võimalik just sellepärast, et DS osutab segmendile DGROUP. Mälumudeli HUGE puhul omab aga iga fail oma andmesegmenti, mis ka sisaldab tema globaalseid muutujaid. Iga faili jaoks on olemas segment nimega <faili nimi>_DATA, mis sisaldab selles failis defineeritud initsialiseeritud muutujaid ja segment nimega <faili nimi>_BSS selles failis defineeritud initsialiseerimata muutujate jaoks. Assemblerprogrammis tuleks siis oma andmesegmendi kasutamiseks kõigepealt laadida selle segmendi aadress registrisse DS, näiteks:

	.MODEL HUGE
	.FARDATA
	DW	number	235
...
	.CODE
	PUBLIC	_func1
_func1	PROC
	push  bp	;loome pinuraami
	mov   bp, sp
	push  ds	;säilitame registri DS endise väärtuse
	mov	ax, @fardata ;loeme oma andmesegmendi aadressi
	mov	ds, ax	 ;registrisse DS
	mov	ax, number   ;teeme midagi selle muutujaga
	...
	pop	ds
	pop	bp
	ret
_func1	ENDP
	END

Kui te aga HUGE mälumudeli puhul tahaksite *.ASM failis kasutada temaga lingitud *.C failis defineeritud muutujaid, siis tekib küsimus - millises segmendis need muutujad on salvestatud ja kust saada segmendi aadressi. Selle probleemi jaoks on vaid üks õige lahendus - kasutada SEG käsku koos muutujanimega ja lasta translaatoril selle probleemiga tegeleda. Kui ülemises näites defineeritud muutuja number oleks olnud defineeritud mingis muus failis, siis oleks tulnud teha järgmist:

	...
	push ds
	mov  ax, SEG _number
	mov  ds, ax
	mov  ax, _number
	...
	pop  ds
	...

Assemblerfailis kasutatavad C - keele funktsioonid tuleb samuti deklareerida võtmesõnaga EXTRN. Kui funktsiooni või muutuja deklaratsioonile või definitsioonile lisada sümbol "C", siis teab Turbo Assembler, et seda muutujat tuleb kasutada C - keele reeglite järgi ja lisab talle ise ka sümboli "_". Nüüd saab ka assemblerfailis kasutada C - keele funktsioone käsu CALL abil. Te võite kas ise salvestada vajalikud parameetrid pinule ja seejärel tolle funktsiooni välja kutsuda, või kasutada sümbolit "C" ja reastada lihtsalt funktsiooni parameetrid temast paremale.

Kohalike muutujate kasutamiseks tuleb nihutada pinuviita (SP) muutujatele ruumi tegemiseks allapoole. Nüüd saab registrit BP kasutada nende muutujate väärtuste lugemiseks ja muutumiseks. Enne funktsiooni lõppu tuleb need muutujad aga pinult eemaldada ja alles seejärel taastada endine BP. Järgmises programmis näete, kuidas kasutada assemblerprogrammis C - keele funktsioone ja kohalikke muutujaid.

ASMDEMO3.C

/*********************************************************/
/***                                                   ***/
/***   AsmDemo3.C                                      ***/
/***                                                   ***/
/***   Näitab globaalsete andmete vahetamist C - keele ***/
/***   ja assemblerfunktsioonide vahel ning C - keele  ***/
/***   funktsioonide kasutamist assemblerfunktsioonis. ***/
/*********************************************************/

/*----------------< Päisefailid >------------------------*/

#include	<stdio.h>

/*----------------< Globaalsed muutujad >----------------*/

struct MyData {
 char	name[20];
 int	amount;
} Data[] = {
 "Peeter", 4,
 "Jaanus", 5,
 "Toomas", 21,
 NULL, 0,
};

char	szFormat[] = "%s omab %d protsenti aktsiatest\n";

/*----------------< Funktsioonide prototüübid >----------*/

extern void ShowData(struct MyData *);
int CalcPercent(int, int);


/*=======================================================*/
/*===                                                 ===*/
/*===   main()                                        ===*/
/*===                                                 ===*/
/*===   Selles programmis kasutatakse failis          ===*/
/*===   ASMBAR.ASM defineeritud funktsioone           ===*/
/*===   soovitud andmete esitamiseks ekraanil         ===*/
/*===   graafilise ringdiagrammina.                   ===*/
/*=======================================================*/
int main( void )
{
  ShowData(&Data);           /* esita diagramm ekraanile */
  return 0;
}	//main





/*-------------------------------------------------------*/
/*---                                                 ---*/
/*---   CalcPercent()                                 ---*/
/*---                                                 ---*/
/*---   Arvutab, kuipalju protsente moodustab arv     ---*/
/*---   nNum arvust nWhole. Seda funktsiooni kasu-    ---*/
/*---   tatakse assemblerfunktsioonis ShowData().     ---*/
/*-------------------------------------------------------*/
int CalcPercent(int nNum, int nWhole)
{
  return (int)((double)nNum /  (double)nWhole * 100.0);
}	/* CalcPercent() */

SHOWDATA.ASM

;**********************************************************
;***                                                    ***
;***   ShowData.ASM                                     ***
;***                                                    ***
;***   Sisaldab assemblerfunktsiooni ShowData(), mis    ***
;***   esitab  ekraanile talle üle antud andmed.        ***
;***   Lisaks sellele näidatakse selles failis, kuidas  ***
;***   kasutada assemblerfunktsioonis kohalikke         ***
;***   muutujaid.                                       ***
;**********************************************************
	DOSSEG
	.MODEL SMALL
;koiki neid C funktsioone saab kasutada assembler funktsioonis
	EXTRN C printf:PROC          ;standardne C funktsioon
	EXTRN C CalcPercent:PROC     ;teises failis defineeritud
                                     ;funktsioon
	.DATA
	EXTRN C szFormat	     ;formaadispetsifikatsioon
	.CODE
	PUBLIC C ShowData
	;Pinuraamil on järgmised andmed:
	; [BP-4]	-	kohalik muutuja - viit struktuurile
	; [BP-2]	- 	kohalik muutuja - kogu summa
	; [BP+0]	-	vana BP
	; [BP+2]	-	tagasipöördumise aadress
	; [BP+4]	-	andmestruktuuri MyStrct aadress
ShowData	PROC	C
	push bp
	mov  bp, sp
	sub  sp, 4	;seda ruumi pinul on vaja kohalike muutujate jaoks
	mov  bx, [BP+4]            ;hangi andmestruktuuri aadress
	mov  word ptr [BP-2], 0	   ;initsialiseeri muutuja
getwhole:
	mov  ax, word ptr [BX+20]  ;hangi antud isiku aktsiate arv
	add  [BP-2], ax	           ;liida tema väärtus kohalikule 
                                   ;muutujale
	add  bx, 22	           ;nihuta viita edasi
	cmp  ax, 0                 ;kontrolli, kas see on viimane arv
	jnz  getwhole              ;kui see ei ole viimane arv, 
                                   ;siis hangi järgmine
	mov  ax, [bp+4]
	mov  [bp-4], ax            ;initsialiseeri viit
show:
	mov  bx, [bp-4]   ;BX voib muutuda, aga kohalik muutuja mitte
			  ;seepärast säilitame aadressi pinul
	mov  ax, [bx+20]
	cmp  ax, 0              ;kontrolli, kas see oli viimane isik
	jz   getout
	call
CalcPercent C, ax, [bp-2]      	;arvuta protsent
	call printf C, OFFSET szFormat, bx, ax  ;väljasta tulemused
	add [bp-4], 22    			;nihuta viita edasi
	jmp show
getout:
	add  sp, 4       ;enne sai SP -st 4 lahutatud, nüüd tuleb
                         ;see uuesti liita

	pop  bp
	ret
ShowData	ENDP
	END